home *** CD-ROM | disk | FTP | other *** search
/ Collection of Tools & Utilities / Collection of Tools and Utilities.iso / tex / sauter.zip / MAKE_MF < prev    next >
Text File  |  1990-11-19  |  2KB  |  65 lines
  1. #! /bin/csh -f
  2. # Make mf source files.
  3.  
  4. if ($#argv < 2) then
  5.    echo "Usage: $0 family_name size [size ...]."
  6.    exit(1)
  7. endif
  8.  
  9. # Remember the family name (e.g., ``cmr'').
  10. set family = $1
  11. shift
  12.  
  13. # Make a mf subdirectory to put the files in.
  14. if (! -d mf) then
  15.    mkdir mf
  16. endif
  17.  
  18. # We don't want the current and future directories to
  19. # be printed on the terminal. (I use pushd instead of cd
  20. # because cd .. will cause havoc if `cd mf' cd'd into
  21. # a symbolic link. (I didn't think of this until I did it.)
  22.  
  23. pushd mf > /dev/null
  24. foreach size ($argv)
  25.    set name_size = $size:r # Lose any decimal digits.
  26.    set mf_name = $family$name_size.mf
  27.  
  28.    # The Computer Modern point sizes are based on the 1.2 ratio.
  29.    # Delete this switch statement if you prefer to have point
  30.    # sizes that are exactly what you type.
  31.  
  32.   switch($size)
  33.   case 11
  34.       set size = 10.954451
  35.       breaksw
  36.    case 14
  37.       set size = 14.4
  38.       breaksw
  39.    case 17
  40.       set size = 17.28
  41.       breaksw
  42.    case 20
  43.       set size = 20.736
  44.       breaksw
  45.    case 25
  46.       set size = 24.8832
  47.       breaksw
  48.    case 30
  49.       set size = 29.8685984
  50.       breaksw
  51.    endsw
  52.  
  53.    # Make sure it doesn't exist already.    
  54.    if (-e $mf_name) then
  55.       echo "$mf_name already exists, so I'm not going to change it."
  56.    else
  57.       echo "% $size-point $family." > $mf_name
  58.       echo "design_size := $size;" >> $mf_name
  59.       echo "input b-$family;" >> $mf_name
  60.    endif
  61. end
  62.  
  63. # Come back to where we were.
  64. popd > /dev/null
  65.